Fonction Excel : LET

La fonction Excel LET affecte un nom aux résultats de calculs afin de stocker et réutiliser des valeurs à l'intérieur d'une formule.

Le but de cette fonction est avant tout d'éviter de calculer plusieurs fois un même résultat dans une même formule. A la place, la fonction LET permet de calculer une seule fois ce résultat et d'attribuer un nom à ce résultat pour pouvoir le réutiliser ensuite dans la formule.

Utilisation :

=LET(nom; valeur; formule)

ou

=LET(nom_1; valeur_1; nom_2; valeur_2; ...; formule)

Exemple simple d'utilisation

Dans cet exemple, la formule suivante multiplie la valeur de la cellule par 4 :

=A2*2+A2*2

Il y a bien sûr beaucoup plus simple pour multiplier un nombre par 4, mais l'objectif ici est d'avoir une formule simple avec un calcul qui se répète.

Pour éviter la répétition de A2*2, enregistrez le résultat de ce calcul à l'aide de la fonction LET et attribuez-lui un nom, par exemple x :

=LET(x;A2*2;

Ajoutez ensuite la formule initiale A2*2+A2*2 en remplaçant A2*2 par x :

=LET(x;A2*2;x+x)

Exemple d'utilisation

Dans ce nouvel exemple, l'objectif est de calculer les commissions des commerciaux en appliquant un taux en fonction du chiffre d'affaire moyen par jour.

La colonne E contient ici la formule qui calcule la moyenne par jour :

=D2/(C2-B2+1)

La formule de la colonne F détermine le taux de commission à appliquer à l'aide de fonctions SI :

=SI(E2>220;2.5;SI(E2>200;2;1.5))

Et la commission est calculée dans la colonne G à l'aide de la formule suivante :

=D2*F2/100

Pour afficher directement le montant des commissions, sans passer par des colonnes intermédiaires (les colonnes grises), il est possible de combiner ces formules en une seule formule :

=D2*SI(D2/(C2-B2+1)>220;2.5;SI(D2/(C2-B2+1)>200;2;1.5))/100

Pour éviter de calculer 2 fois la moyenne par jour D2/(C2-B2+1) et rendre la formule un peu plus lisible, enregistrez le résultat du calcul de la moyenne à l'aide de la fonction LET :

=LET(moyenneJour;D2/(C2-B2+1);

Et ajoutez la formule complète en 3^e argument en remplaçant D2/(C2-B2+1) par le nom défini :

=LET(moyenneJour;D2/(C2-B2+1);D2*SI(moyenneJour>220;2.5;SI(moyenneJour>200;2;1.5))/100)